Hallo,

kann mir jemand sagen, wie ich herausfinde, in welchen Formularen ein bestimmter Standardtext verwendet wird?

Danke

Morgana

Hallo Morgana,

mit beiliegendem Programm kannst Du zumindest einzelne Forrmulare absuchen.

Gruß

Lupus  

REPORT  Z_MM_SUCHTEXT.

TABLES: STXH, TLINE, THEAD.

DATA:  ILINES LIKE TABLE OF TLINE WITH HEADER LINE.

DATA: LCOUNTER TYPE I.

PARAMETERS: TDNAME   LIKE STXH-TDNAME DEFAULT 'Formularname?',

            TDSPRAS  LIKE STXH-TDSPRAS DEFAULT 'DE',

            SUCHTEXT(50) DEFAULT 'Name Standard-Text?'.

START-OF-SELECTION.

  CALL FUNCTION 'READ_TEXT'

    EXPORTING

      ID       = 'TXT'

      LANGUAGE = TDSPRAS

      NAME     = TDNAME

      OBJECT   = 'FORM'

    TABLES

      LINES    = ILINES.

  LOOP AT ILINES.

     IF ILINES-TDLINE CS SUCHTEXT.

      WRITE: /2 ILINES-TDLINE.

      LCOUNTER =  LCOUNTER + 1.

    ENDIF.

  ENDLOOP.

  IF LCOUNTER = 0.

    WRITE: /  SUCHTEXT, 'nicht in Formular enthalten!'.

  ENDIF.

Hallo,
damit kann man einen bestimmten Text in allen Formularen durchsuchen...
Es geht aber nur, wenn der Text "hart" inkludiert wird, nicht wenn er über eine Variable gezogen wird, klar!
(Hiermit kann man eigentlich nach einem beliebigen SAPScript-Kommando '/:' in den Formularen suchen)

Gruß,
sy-tabix

*=======================================================================
* Datendeklarationen
*=======================================================================
DATA: gt_stxh TYPE TABLE OF stxh,
      gs_stxh TYPE stxh,
      gt_lines TYPE TABLE OF tline,
      BEGIN OF gs_stxl_id,
       tdobject LIKE stxl-tdobject,
       tdname   LIKE stxl-tdname,
       tdid     LIKE stxl-tdid,
       tdspras  LIKE stxl-tdspras,
      END OF gs_stxl_id.
*=======================================================================
* Selektionsbildschirm
*=======================================================================
PARAMETERS:
  p_tname TYPE tdobname OBLIGATORY. "obligatorisch, weil sonst sinnlos

*=======================================================================
* START-OF-SELECTION.
*=======================================================================
START-OF-SELECTION.

* Alle Formularköpfe (in Sprache DE und aktuellen Mandant) einlesen
  SELECT * FROM stxh INTO TABLE gt_stxh
                WHERE tdobject = 'FORM' AND
                      tdid     = 'TXT' AND
                      tdspras  = 'DE'.

  LOOP AT gt_stxh INTO gs_stxh.
    REFRESH gt_lines.
    MOVE-CORRESPONDING gs_stxh TO gs_stxl_id.
* Formularinhalt (aus Datencluster) lesen
    IMPORT tline TO gt_lines
      FROM DATABASE stxl(tx)
           CLIENT   sy-mandt
           ID       gs_stxl_id.
* Im Formular nach dem eingegebenen String suchen
    LOOP AT gt_lines TRANSPORTING NO FIELDS
         WHERE tdformat = '/:'    "SAPScript-Kommando
           AND tdline CS p_tname.
      EXIT.
    ENDLOOP.
    CHECK sy-subrc = 0.
    WRITE: / 'Text', p_tname(30), 'im Formular', gs_stxh-tdname(16),
           'gefunden!'.
  ENDLOOP.